Yet another flag post

package net.xerode.demo {
 
	import flash.display.BlendMode;
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.BitmapDataChannel;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.filters.BlurFilter;
	import flash.filters.DisplacementMapFilter;
	import flash.filters.DisplacementMapFilterMode;
	import flash.filters.DropShadowFilter;
	import flash.geom.ColorTransform;
	import flash.geom.Matrix;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import flash.filters.BitmapFilterQuality;
 
	import net.xerode.util.Maths;
 
	public class Perlin extends Sprite {
 
		private var flag:Sprite;
		private var bmd:BitmapData;
		private var seed:Number = 0;
		private var lifespan:uint = 0;
		private var flagData:BitmapData;
		private var salute:Sprite;
		private var result:Bitmap;
 
		private var oldFrame:BitmapData;
 
		public function Perlin( ) {
 
			trace( "Perlin demo start" );
 
			setup( );
 
		}
 
		private function setup( ):void {
 
			seed = Math.floor( Math.random( ) * 10 );
 
			// AnonFlag( ) is just the MovieClip library item that contains the flag image
			flag = new AnonFlag( );
 
			flagData = new BitmapData( flag.width, flag.height );
			flagData.draw( flag );
 
			result = new Bitmap( flagData )
 
			addChild( result );
 
			// Salute( ) is just the MovieClip library item that contains the foreground photo
			salute = new Salute( );
			salute.x = 150;
			salute.y = 35;
 
			salute.filters = new Array( new DropShadowFilter( 8, -45, 0x000000, 0.5, 32, 32 ) );
 
			addChild( salute );
 
			addEventListener( Event.ENTER_FRAME, animateFlag );
 
		}
 
		private function drawPerlin( ):void {
 
			bmd = new BitmapData( 450, 270, true, 0x00ffffff );
 
			var octaves:uint = 2;
 
			var offsets:Array = new Array( );
 
			for( var i:uint = 0; i < octaves; i++ ) {
 
				var ny:Number = Math.sin( Maths.deg2Rad( lifespan / ( stage.frameRate * 4 ) * 360 ) ) * 50;
 
				var pt:Point = new Point( ( lifespan / stage.frameRate ) * 300 * ( i / octaves ), ny );
 
				offsets.push( pt );
 
			}
 
			bmd.perlinNoise( 90, 135, octaves, seed, true, true, 7, true, offsets );  
 
			var cloned:BitmapData = bmd.clone( );
 
			bmd.applyFilter( cloned, bmd.rect, new Point( 0, 0 ), new BlurFilter( 4, 4, BitmapFilterQuality.LOW ) );
 
			var displaceX:Number = ( Math.sin( Maths.deg2Rad( lifespan / ( stage.frameRate * 1.2 ) * 360 )  ) * 5 ) + 15;
 
			var displaceY:Number = ( Math.sin( Maths.deg2Rad( lifespan / ( stage.frameRate * 0.8 ) * 360 )  ) * 5 ) + 35;
 
			flagData.lock( );
 
			// Get snapshot of flag
			flagData.draw( flag );
 
			// Merge with map for shading
			flagData.draw( bmd, null, new ColorTransform( 1, 1, 1, 0.25 ), BlendMode.HARDLIGHT );
			flagData.draw( bmd, null, new ColorTransform( 1, 1, 1, 0.5 ), BlendMode.OVERLAY );
 
			// Merge with previous frame
			if( lifespan > 0 ) {
				// flagData.draw( oldFrame, null, new ColorTransform( 1, 1, 1, 0.25 ), BlendMode.NORMAL );
			}
 
			flagData.lock( );
 
			// trace( displaceY );
			var bumpMap:DisplacementMapFilter = new DisplacementMapFilter( bmd, new Point( 0, 0 ), BitmapDataChannel.RED, BitmapDataChannel.BLUE, displaceX, displaceY, DisplacementMapFilterMode.CLAMP );
			result.filters = new Array( bumpMap );
 
			lifespan += 1;
 
			oldFrame = flagData.clone( );
 
		}
 
		private function animateFlag( e:Event ):void {
 
			drawPerlin( );
 
		}
 
	}
 
}